apply plugin: 'com.android.application'

// TODO: remove this after closed beta
apply plugin: 'com.google.gms.google-services'

import com.android.build.OutputFile

/**
 * The react.gradle file registers a task for each build variant (e.g. bundleDebugJsAndAssets
 * and bundleReleaseJsAndAssets).
 * These basically call `react-native bundle` with the correct arguments during the Android build
 * cycle. By default, bundleDebugJsAndAssets is skipped, as in debug/dev mode we prefer to load the
 * bundle directly from the development server. Below you can see all the possible configurations
 * and their defaults. If you decide to add a configuration block, make sure to add it before the
 * `apply from: "../../node_modules/react-native/react.gradle"` line.
 *
 * project.ext.react = [
 *   // the name of the generated asset file containing your JS bundle
 *   bundleAssetName: "index.android.bundle",
 *
 *   // the entry file for bundle generation. If none specified and
 *   // "index.android.js" exists, it will be used. Otherwise "index.js" is
 *   // default. Can be overridden with ENTRY_FILE environment variable.
 *   entryFile: "index.android.js",
 *
 *   // https://reactnative.dev/docs/performance#enable-the-ram-format
 *   bundleCommand: "ram-bundle",
 *
 *   // whether to bundle JS and assets in debug mode
 *   bundleInDebug: false,
 *
 *   // whether to bundle JS and assets in release mode
 *   bundleInRelease: true,
 *
 *   // whether to bundle JS and assets in another build variant (if configured).
 *   // See http://tools.android.com/tech-docs/new-build-system/user-guide#TOC-Build-Variants
 *   // The configuration property can be in the following formats
 *   //         'bundleIn${productFlavor}${buildType}'
 *   //         'bundleIn${buildType}'
 *   // bundleInFreeDebug: true,
 *   // bundleInPaidRelease: true,
 *   // bundleInBeta: true,
 *
 *   // whether to disable dev mode in custom build variants (by default only disabled in release)
 *   // for example: to disable dev mode in the staging build type (if configured)
 *   devDisabledInStaging: true,
 *   // The configuration property can be in the following formats
 *   //         'devDisabledIn${productFlavor}${buildType}'
 *   //         'devDisabledIn${buildType}'
 *
 *   // the root of your project, i.e. where "package.json" lives
 *   root: "../../",
 *
 *   // where to put the JS bundle asset in debug mode
 *   jsBundleDirDebug: "$buildDir/intermediates/assets/debug",
 *
 *   // where to put the JS bundle asset in release mode
 *   jsBundleDirRelease: "$buildDir/intermediates/assets/release",
 *
 *   // where to put drawable resources / React Native assets, e.g. the ones you use via
 *   // require('./image.png')), in debug mode
 *   resourcesDirDebug: "$buildDir/intermediates/res/merged/debug",
 *
 *   // where to put drawable resources / React Native assets, e.g. the ones you use via
 *   // require('./image.png')), in release mode
 *   resourcesDirRelease: "$buildDir/intermediates/res/merged/release",
 *
 *   // by default the gradle tasks are skipped if none of the JS files or assets change; this means
 *   // that we don't look at files in android/ or ios/ to determine whether the tasks are up to
 *   // date; if you have any other folders that you want to ignore for performance reasons (gradle
 *   // indexes the entire tree), add them here. Alternatively, if you have JS files in android/
 *   // for example, you might want to remove it from here.
 *   inputExcludes: ["android/**", "ios/**"],
 *
 *   // override which node gets called and with what additional arguments
 *   nodeExecutableAndArgs: ["node"],
 *
 *   // supply additional arguments to the packager
 *   extraPackagerArgs: []
 * ]
 */

project.ext.react = [
    enableHermes: false,  // clean and rebuild if changing
    entryFile: "index.ts",
    nodeExecutableAndArgs: ["node", "--max-old-space-size=4096"], // fixes OOM error during js build, from https://stackoverflow.com/a/42568929/18204329
]

apply from: "../../node_modules/react-native/react.gradle"

/**
 * Set this to true to create two separate APKs instead of one:
 *   - An APK that only works on ARM devices
 *   - An APK that only works on x86 devices
 * The advantage is the size of the APK is reduced by about 4MB.
 * Upload all the APKs to the Play Store and people will download
 * the correct one based on the CPU architecture of their device.
 */
def enableSeparateBuildPerCPUArchitecture = true

/**
 * Run Proguard to shrink the Java bytecode in release builds.
 */
def enableProguardInReleaseBuilds = true

/**
 * The preferred build flavor of JavaScriptCore.
 *
 * For example, to use the international variant, you can use:
 * `def jscFlavor = 'org.webkit:android-jsc-intl:+'`
 *
 * The international variant includes ICU i18n library and necessary data
 * allowing to use e.g. `Date.toLocaleString` and `String.localeCompare` that
 * give correct results when using with locales other than en-US.  Note that
 * this variant is about 6MiB larger per architecture than default.
 */
def jscFlavor = 'org.webkit:android-jsc:+'

/**
 * Whether to enable the Hermes VM.
 *
 * This should be set on project.ext.react and mirrored here.  If it is not set
 * on project.ext.react, JavaScript will not be compiled to Hermes Bytecode
 * and the benefits of using Hermes will therefore be sharply reduced.
 */
def enableHermes = project.ext.react.get("enableHermes", false);

android {
    compileSdkVersion rootProject.ext.compileSdkVersion
    ndkVersion rootProject.ext.ndkVersion

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    defaultConfig {
        applicationId "tech.berty.android"
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion

        missingDimensionStrategy 'react-native-camera', 'general'
        multiDexEnabled true // fix for "The number of method references in a .dex file cannot exceed 64K"
        vectorDrawables.useSupportLibrary = true // needed for image picker

        def addEnvVar = {key ->
            def value = getEnvValue(key)
            manifestPlaceholders += [(key):value]
            buildConfigField "String", "${key}", "\"${value}\""
        }

        addEnvVar("SHAKE_API_ID")
        addEnvVar("SHAKE_API_SECRET")

        def generateVersionCode = {
            def cwd = rootDir.getParentFile().getParentFile() // Berty repo root dir
            def platform = System.properties['os.name'].toLowerCase().contains('windows') ? "Windows" : "Unix"
            def err
            try {
                def proc = "${platform == "Windows" ? "PowerShell -Command" : ""} git rev-list HEAD --count".execute(null, cwd)
                err = proc.err.text.trim()
                def out = proc.text.trim()
                if (!out.isEmpty()) {
                    if (out.isInteger()) {
                        return out.toInteger()
                    }
                    err = "can't convert version code to integer: <${out}>"
                }
            } catch (Exception e) {
                err = e.toString()
            }
            throw new RuntimeException("Could not generate versionCode (platform ${platform}): ${err}")
        }

        def generateVersionName = {
            def cwd = rootDir.getParentFile().getParentFile() // Berty repo root dir
            def platform = System.properties['os.name'].toLowerCase().contains('windows') ? "Windows" : "Unix"
            def err
            try {
                def proc = "${platform == "Windows" ? "PowerShell -Command" : ""} go run -mod=readonly github.com/mdomke/git-semver/v5".execute(null, cwd)
                err = proc.err.text.trim()
                def out = proc.text.trim()
                if (!out.isEmpty()) {
                    out = out.substring(1)
                    out = out.split('-')[0]
                    return out
                }
            } catch (Exception e) {
                err = e.toString()
            }
            throw new RuntimeException("Could not generate versionName (platform ${platform}): ${err}")
        }

        versionCode generateVersionCode()
        versionName generateVersionName()
    }
    splits {
        abi {
            reset()
            enable enableSeparateBuildPerCPUArchitecture
            universalApk false  // If true, also generate a universal APK
            include "armeabi-v7a", "x86", "arm64-v8a", "x86_64"
        }
    }
    signingConfigs {
        debug {
            storeFile file('debug.keystore')
            storePassword 'android'
            keyAlias 'androiddebugkey'
            keyPassword 'android'
        }
    }
    buildTypes {
        debug {
            applicationIdSuffix ".debug"
            signingConfig signingConfigs.debug
            buildConfigField "boolean", "DEBUG_LOGS", "true"
        }
        release {
            // Caution! In production, you need to generate your own keystore file.
            // see https://reactnative.dev/docs/signed-apk-android.
            signingConfig signingConfigs.debug
            minifyEnabled enableProguardInReleaseBuilds
            shrinkResources true
            proguardFiles getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro"
            buildConfigField "boolean", "DEBUG_LOGS", "false"
        }
        releaseStaff {
            initWith release
            applicationIdSuffix ".staff"
            matchingFallbacks = ['release']
            buildConfigField "boolean", "DEBUG_LOGS", "true"
        }
        releaseYolo {
            initWith release
            applicationIdSuffix ".yolo"
            matchingFallbacks = ['release']
            buildConfigField "boolean", "DEBUG_LOGS", "true"
        }
    }

    // applicationVariants are e.g. debug, release
    applicationVariants.all { variant ->
        variant.outputs.each { output ->
            // For each separate APK per architecture, set a unique version code as described here:
            // https://developer.android.com/studio/build/configure-apk-splits.html
            // Example: versionCode 1 will generate 1001 for armeabi-v7a, 1002 for x86, etc.
            def versionCodes = ["armeabi-v7a": 1, "x86": 2, "arm64-v8a": 3, "x86_64": 4]
            def abi = output.getFilter(OutputFile.ABI)
            if (abi != null) {  // null for the universal-debug, universal-release variants
                output.versionCodeOverride =
                    defaultConfig.versionCode * 1000 + versionCodes.get(abi)
            }

        }
    }

    packagingOptions {
        // Make sure libjsc.so does not packed in APK
        exclude "**/libjsc.so"
    }
}

// Auto-build gomobile.aar by running Makefile rule
task makeDeps(description: 'Build gomobile.aar (Berty go core)') {
    outputs.files fileTree(dir: "${rootDir.getPath()}/libs", include: ["*.jar", "*.aar"])

    doLast {
        if (System.properties['os.name'].toLowerCase().contains('windows')) {
            logger.warn("Warning: can't run make on Windows, you must build gomobile.aar manually")
            return
        }

        def checkMakeInPath = exec {
            standardOutput = new ByteArrayOutputStream() // equivalent to '> /dev/null'
            ignoreExitValue = true
            commandLine 'bash', '-l', '-c', 'command -v make'
        }

        if (checkMakeInPath.getExitValue() == 0) {
            exec {
                def makefileDir = "${rootDir.getPath()}/.."
                workingDir makefileDir
                environment 'PWD', makefileDir
                commandLine 'make', 'android.app_deps'
            }
        } else {
            logger.warn('Warning: make command not found in PATH')
        }
    }
}

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])
    //noinspection GradleDynamicVersion
    implementation "com.facebook.react:react-native:+"  // From node_modules

    // firebase fcm
    implementation platform('com.google.firebase:firebase-bom:28.1.0')
    implementation 'com.google.firebase:firebase-messaging'

    // Add v8-android - prebuilt libv8android.so into APK
    implementation 'org.chromium:v8-android:9.88.+'

    implementation 'androidx.viewpager2:viewpager2:1.0.0'

    implementation 'com.facebook.fresco:animated-gif:2.0.0' // For animated GIF support

    implementation "androidx.swiperefreshlayout:swiperefreshlayout:1.0.0"

    implementation project(':react-native-share')

    // Add Android Nearby
    implementation "com.google.android.gms:play-services-nearby:16.0.0"
    implementation 'com.google.android.gms:play-services-location:17.0.0'
    implementation 'androidx.lifecycle:lifecycle-process:2.3.1'

    // Add keystore, 1.1 is required to use the MasterKey class
    implementation "androidx.security:security-crypto:1.1.0-alpha03"

    debugImplementation("com.facebook.flipper:flipper:${FLIPPER_VERSION}") {
      exclude group:'com.facebook.fbjni'
    }

    debugImplementation("com.facebook.flipper:flipper-network-plugin:${FLIPPER_VERSION}") {
        exclude group:'com.facebook.flipper'
        exclude group:'com.squareup.okhttp3', module:'okhttp'
    }

    debugImplementation("com.facebook.flipper:flipper-fresco-plugin:${FLIPPER_VERSION}") {
        exclude group:'com.facebook.flipper'
    }

    if (enableHermes) {
        def hermesPath = "../../node_modules/hermes-engine/android/";
        debugImplementation files(hermesPath + "hermes-debug.aar")
        releaseImplementation files(hermesPath + "hermes-release.aar")
    } else {
        implementation jscFlavor
    }

    implementation makeDeps.outputs.files
}

// Run this once to be able to run the application with BUCK
// puts all compile dependencies into folder libs for BUCK to use
task copyDownloadableDepsToLibs(type: Copy) {
    from configurations.compile
    into 'libs'
}

apply from: file("../../node_modules/@react-native-community/cli-platform-android/native_modules.gradle"); applyNativeModulesAppBuildGradle(project)


project.ext.vectoricons = [
    iconFontNames: [ 'Feather.ttf' ] // Name of the font files you want to copy
]

apply from: "../../node_modules/react-native-vector-icons/fonts.gradle"
